Позиционирование значков рабочего стола слева, а не справа

Любой способ автоматического создания псевдонимов или значков для отображения на левой стороне рабочего стола Apple. По умолчанию они идут вправо.

10
ja de
Это одно из решений в macOS, которое я не понимаю. Почему Apple вынуждает пользователей иметь значки справа? Вы можете перетащить их влево, но это не главное. Когда вы сортируете их по имени, все возвращается вправо. Даже когда вы открываете каталог Desktop в Finder, значки выравниваются влево! Это непоследовательно. У меня есть мой системный язык, установленный слева направо, один, а не арабский или иврит ... Это знаменитый пользовательский интерфейс Apple?
добавлено автор Randy Stegbauer, источник

4 ответы

Невозможно заставить иконки автоматически перемещаться влево (и оставаться в соответствии с выбранным вами критерием).

В качестве обходного пути вы можете изменить Параметры просмотра в Finder, чтобы не упорядочивать элементы по какому-либо критерию и размещать значки вручную слева.

  • Click on an empty space on the desktop.
  • Press Cmd+J or use the mouse to go to the Finder's View > Show View Options menu.
  • In the Sort by: dropdown in the dialog, choose either None or Snap to Grid.
  • You'll be able to drop files anywhere on your desktop and they'll stay there.

Подробнее см. Основы Mac: измените свои окна .

Также просмотрите страницы Mac Основы , чтобы узнать больше об использовании Mac. </сильный>

7
добавлено
Благодарю. Я пропустил автоматическую часть и исправил ответ.
добавлено автор Sam Weaver, источник
Q спрашивает об автоматическом выборе «Очистить и сортировать», как мне кажется, в меню «Finder View» - и это было бы круто. Почему только организовать право?
добавлено автор Zo219, источник

Это не лучшее решение, но оно может работать, если ничего не делает ...

  1. Create an Automator Folder Action associated with the Desktop.
  2. Add the item: "run applescript"
  3. Paste the following code in the applescript text box:

    -- https://gist.github.com/mrienstra/8330528
    -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
    -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
    
    -- Rearranges Desktop icons to flow from left to right, top to bottom.
    
    -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
    
    -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
    
    -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
    
    
    
    -- Adjust these for different spacing
    property theSpacingFactor : 1.0
    property theGutterXFactor : 0.57
    property theGutterYFactor : 0.57
    
    
    
    on rearrangeDesktopIcons()
        tell application "Finder"
            tell icon view options of window of desktop
                set theArrangement to arrangement
                set theArrangementString to theArrangement as string
                if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                    display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                    return
                end if
                set theIconSize to icon size
                set theLabelSize to text size
            end tell
    
            set theDesktopBounds to bounds of window of desktop
            set theDesktopWidth to item 3 of theDesktopBounds
            set theDesktopHeight to item 4 of theDesktopBounds
    
            -- Retrieve a list of items on the desktop
            set theDesktopItems to every item of desktop
            set theContestantOffset to theIconSize/2
    
            set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
            set theGuttersX to theSpacing * theGutterXFactor
            set theGuttersY to theSpacing * theGutterYFactor
            set theMaxColumns to ((theDesktopWidth - theGuttersX * 2)/theSpacing) as integer
            set theMaxRows to ((theDesktopHeight - theGuttersY * 2)/theSpacing) as integer
            set theMaxLocations to theMaxRows * theMaxColumns
    
            set y to 1
            repeat with a from 1 to length of theDesktopItems
                set x to a mod theMaxColumns
                if x is 0 then
                    set x to theMaxColumns
                end if
    
                if a is greater than theMaxLocations then
                    set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
                else
                    set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
                end if
    
                if a mod theMaxColumns is 0 then
                    set y to y + 1
                end if
            end repeat
        end tell
    end rearrangeDesktopIcons
    
    
    
    on adding folder items to alias after receiving listOfAlias
        rearrangeDesktopIcons()
    end adding folder items to
    
    on removing folder items from alias after losing listOfAliasOrText
        rearrangeDesktopIcons()
    end removing folder items from
    
    rearrangeDesktopIcons()
    

Поэтому всякий раз, когда файл добавляется на рабочий стол, все файлы будут перегруппированы по алфавиту ...

2
добавлено

Я просто выделил все папки с правой стороны, затем схватил их всех и вставил влево.

2
добавлено

Организуйте все папки в том порядке, в котором вы хотите. Затем в разделе «Просмотр» нажмите «Очистить». Это будет хорошо сочетать все. Затем вы можете просто выделить все папки и разместить их именно там, где вы хотите. Маки не упорядочивают папки слева, только правые, но с помощью нескольких простых шагов вы можете все, что аккуратно организовано слева.

0
добавлено
Это должно читать «вид» вместо «окна», извините, это было плохо.
добавлено автор rouble, источник
Рядом с ответом есть ссылка на редактирование, которая позволяет редактировать текст напрямую :-)
добавлено автор Andrew Dunaway, источник
macOS — русскоговорящее сообщество
macOS — русскоговорящее сообщество
693 участник(ов)

Обсуждаем всё, что связано с экосистемой macOS и продуктами Apple.

macOS Developers — русскоговорящее сообщество
macOS Developers — русскоговорящее сообщество
124 участник(ов)

По всем остальным macOS / Apple вопросам в @macOS_ru Обсуждаем всё, что связано с разработкой под macOS.